Description :
Cette fonction retourne un pointeur vers la connexion internet courante.
sAgent est une chaîne indiquant le nom de l'application initiant le dialogue.
lAccessType indique le type d'accès désiré. Voir le tableau des constantes autorisée plus bas.
sProxyName donne le nom du proxy à utiliser. Uniquement si l'accès utilise la constante INTERNET_OPEN_TYPE_PROXY.
sProxyBypass contient une liste d'adresse à ne pas prendre en compte pour un accès par proxy. Uniquement avec INTERNET_OPEN_TYPE_PROXY.
lFlags peut contenir une combinaison de constante ci-dessous (INTERNET_FLAG_xxx).
Si la fonction échoue, elle retourne une valeur nulle, sinon elle retourne un pointeur vers la connexion courante.

Exemple d'utilisation :

Public Declare Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" ( _
                    ByVal sAgent As String, ByVal lAccessType As Long, _
                    ByVal sProxyName As String, ByVal sProxyBypass As String, _
                    ByVal lFlags As Long) As Long
Public Declare Function InternetOpenUrl Lib "wininet.dll" Alias "InternetOpenUrlA" ( _
                    ByVal hInternetSession As Long, ByVal sUrl As String, _
                    ByVal sHeaders As String, ByVal lHeadersLength As Long, _
                    ByVal lFlags As Long, ByVal lContext As Long) As Long
Public Declare Function InternetReadFile Lib "wininet.dll" ( _
                    ByVal hFile As Long, ByVal sBuffer As String, _
                    ByVal lNumBytesToRead As Long, _
                    lNumberOfBytesRead As Long) As Integer
Public Declare Function InternetCloseHandle Lib "wininet.dll" ( _
                    ByVal hInet As Long) As Integer

Public Const INTERNET_FLAG_NO_CACHE_WRITE = &H4000000 ' Pas d'écriture en cache

Public Function GetUrlFile(stUrl As String) As String
' Récupère le contenu d'une page/d'un fichier sur internet
Dim lgInternet As Long, lgSession As Long
Dim stBuf As String * 1024
Dim inRes As Integer
Dim lgRet As Long
Dim stTotal As String
stTotal = vbNullString
' Récupère un pointeur vers la connexion internet courante
lgSession = InternetOpen("VBTagEdit", 1, vbNullString, vbNullString, 0)
If lgSession Then
    ' Récupère un pointeur vers l'URL
    lgInternet = InternetOpenUrl(lgSession, stUrl, vbNullString, _
                                 0, INTERNET_FLAG_NO_CACHE_WRITE, 0)
    If lgInternet Then
        Do
            ' Lecture de la page dans le buffer (par bloc de 1024)
            inRes = InternetReadFile(lgInternet, stBuf, 1024, lgRet)
            stTotal = stTotal & Mid$(stBuf, 1, lgRet)
        Loop While (lgRet <> 0)
    End If
    ' Libération du pointeur
    inRes = InternetCloseHandle(lgInternet)
End If
' Retourne le résultat
GetUrlFile = stTotal
End Function

Retour à la liste des API